[自製作業系統] 第18回 實現用戶進程(上)
- 2022 年 8 月 15 日
- 筆記
目錄
一、前景回顧
二、任務切換相關
三、實現TSS
四、運行測試
在上一回我們已經實現了鍵盤的驅動編寫和環形緩衝區的實現，現在讓我們來想這麼一個問題：
一直以來我們的程式都在最高特權級0下工作，這意味著任何程式都和作業系統平起平坐，可以改動任何資源。如果不改變這種現狀的話，某個不聽話的程式甚至可以給作業系統致命一擊，取而代之，那麼後果將不堪設想。所以從本回開始，我們便要開始著手實現用戶進程，讓我們的作業系統看起來更安全一點。
下面的是我自己的一些見解。
如果讓我來設計任務切換，比較簡單的一種思路便是：
首先我們常說的任務，就是一個程式而已，程式在記憶體中被分為程式碼段和數據段。所以我們表徵多個任務，那麼便是多個程式碼段和數據段而已。至於任務的切換，可能需要費點心思在軟體層面上實現多任務調度機制。
然後現在問題出現了：
我們知道程式碼段和數據段需要在全局描述符表GDT中存儲，一個任務需要兩個描述符來存儲，而我們知道全局描述符表GDT最多也就只有2^13=8192個段描述符，那麼理論上也就只能容納4096個任務，除此之外在軟體層面上實現的多任務調度機制有點類似今天的用戶態多執行緒，效率不高且安全性有諸多問題。
所以我們來看看硬體廠商和CPU廠商是如何解決任務切換的問題的，其中最主要的就是LDT和TSS。
首先是LDT。
LDT是局部描述符表，用來存儲每個任務自己的私有實體資源，也就是程式碼和數據。LDT的地址被保存在一個段描述符中，那麼理論上我們現在可以支援8192個任務了。對於當前運行的任務，其LDT的地址被存儲在LDTR暫存器中，這樣CPU就能根據這個地址從中拿到任務所需要的資源。每切換一個任務時，需要用lldt指令重新載入新任務的LDT地址到LDTR暫存器中。
隨後便是TSS。
單核CPU要想實現多任務，唯一的方法便是多任務共享一個CPU，也就是讓多個任務輪流使用CPU。前面說道，LDT是每個任務的私有資源，所以不用擔心多任務時，程式的運行資源會混亂。但這還不夠。
CPU執行任務時，需要把任務所需要的數據載入到暫存器、棧和記憶體中，因為CPU只能直接處理這些資源中的數據，這是CPU在設計之初時工程師們決定的。於是，問題來了，任務的數據和指令是CPU的處理對象，他們被存放在記憶體這個低速的容器中，對於CPU來講，記憶體的速度太慢了，它最喜歡暫存器。因此記憶體中的數據往往被載入到高速的暫存器中後再處理，等處理完畢後再將結果寫入到記憶體中，所以，任何時候，暫存器中的內容才是任務的最新狀態。當任務被換下CPU後，任務的最新狀態應該被保存在某個地方，以便下次重新將此任務調度到CPU時可以恢復此任務的最新狀態，這樣任務才能繼續執行。
於是TSS就出現了，TSS是程式設計師為任務單獨定義的一個結構體變數，當載入新任務時，CPU自動把當前任務（舊任務）的狀態存入當前任務的TSS，然後將新任務TSS中的數據載入到對應的暫存器中。
TSS和其他段也是一樣的，本質上是一片存儲數據的記憶體區域，也需要某個描述符結構來描述它，這就是TSS描述符。
和LDT一樣，CPU對TSS的處理也採用了類似的方法，提供一個名為TR的暫存器來存放當前任務的TSS位置。
總結一下，如圖所示：
CPU原生支援的任務切換方式是針對每一個任務都有一個LDT和一個TSS結構，這種任務切換方式，在任務切換時效率比較低，所以現代作業系統並未採納。現代作業系統放棄了LDT，只採用了TSS，但是也沒有完全採納。我們是效仿Linux的任務切換方式的，所以拿Linux為例。
Linux為每一個CPU創建一個TSS，在各個CPU上的所有任務共享一個TSS，各CPU的TR暫存器保存各CPU上的TSS，也就是說在用ltr指令載入TSS後，該TR暫存器永遠指向同一個TSS，之後再也不會切換了。在進程切換時只需要把TSS中的SS0和esp0更新為新任務的內核棧的段地址和棧指針。
那麼任務的狀態資訊保存在哪裡呢?
對於Linux來講，Linux只在TSS中初始化esp0和SS0以及IO點陣圖。當CPU從低特權級進入高特權級時，也就是3特權級的用戶態到0特權級的內核態時（Linux只有兩個特權級）CPU會自動從TSS中獲取到0特權級的棧指針，然後Linux手動執行一系列的push指令將任務的狀態保存在0特權級的棧中。這個地方先留一下懸念，等後面實現的時候會再次提到。
雖然我們不完全採納TSS，但是因為TSS是硬體所要求的，所以我們必須構造一個TSS來應付硬體。在project/userprog目錄下新建tss.c和tss.h文件，除此之外還需要在global.h文件中新加部分程式碼。
1 #include "global.h"
2 #include "thread.h"
3 #include "print.h"
4 #include "string.h"
5 #include "tss.h"
6
7 struct tss {
8 uint32_t backlink;
9 uint32_t *esp0;
10 uint32_t ss0;
11 uint32_t *esp1;
12 uint32_t ss1;
13 uint32_t *esp2;
14 uint32_t ss2;
15 uint32_t cr3;
16 uint32_t (*eip) (void);
17 uint32_t eflags;
18 uint32_t eax;
19 uint32_t ecx;
20 uint32_t edx;
21 uint32_t ebx;
22 uint32_t esp;
23 uint32_t ebp;
24 uint32_t esi;
25 uint32_t edi;
26 uint32_t es;
27 uint32_t cs;
28 uint32_t ss;
29 uint32_t ds;
30 uint32_t fs;
31 uint32_t gs;
32 uint32_t ldt;
33 uint32_t trace;
34 uint32_t io_base;
35 };
36
37 static struct tss tss;
38
39 /*更新tss中的esp0欄位的值為pthread的0級棧*/
40 void update_tss_esp(struct task_struct *pthread)
41 {
42 tss.esp0 = (uint32_t *)((uint32_t)pthread + PG_SIZE);
43 }
44
45 /*創建gdt描述符*/
46 static struct gdt_desc make_gdt_desc(uint32_t *desc_addr, uint32_t limit, uint8_t attr_low, uint8_t attr_high)
47 {
48 uint32_t desc_base = (uint32_t)desc_addr;
49 struct gdt_desc desc;
50 desc.limit_low_word = limit & 0x0000ffff;
51 desc.base_low_word = desc_base & 0x0000ffff;
52 desc.base_mid_byte = ((desc_base & 0x00ff0000) >> 16);
53 desc.base_high_byte = (desc_base >> 24);
54 desc.attr_low_byte = (uint8_t)attr_low;
55 desc.limit_high_attr_high = (((limit & 0x000f0000) >> 16) + (uint8_t)attr_high);
56 return desc;
57 }
58
59 /*在gdt中創建tss並重新載入gdt*/
60 void tss_init(void)
61 {
62 put_str("tss_init start \n");
63 uint32_t tss_size = sizeof(tss);
64 memset(&tss, 0, tss_size);
65 tss.ss0 = SELECTOR_K_STACK;
66 tss.io_base = tss_size;
67 /*gdt的基地址為0x900，把tss放到第4個地址，也就是0x900+0x20的位置*/
68 *((struct gdt_desc *)0xc0000920) = make_gdt_desc((uint32_t *)&tss, tss_size - 1, TSS_ATTR_LOW, TSS_ATTR_HIGH);
69 /*為用戶進程提前作準備*/
70 /*在gdt中添加dpl為3的數據段和程式碼段描述符*/
71 *((struct gdt_desc *)0xc0000928) = make_gdt_desc((uint32_t *)0, 0xfffff, GDT_CODE_ATTR_LOW_DPL3, GDT_ATTR_HIGH);
72 *((struct gdt_desc *)0xc0000930) = make_gdt_desc((uint32_t *)0, 0xfffff, GDT_DATA_ATTR_LOW_DPL3, GDT_ATTR_HIGH);
73 //while(1);
74 /*gdt 16位的limit 32位的段基址*/
75 uint64_t gdt_operand = ((8 * 7 - 1) | ((uint64_t)(uint32_t)0xc0000900 << 16));
76 asm volatile ("lgdt %0" : : "m" (gdt_operand));
77 asm volatile ("ltr %w0" : : "r" (SELECTOR_TSS));
78
79 put_str("tss_init and ltr done\n");
80 }
tss.c
1 #ifndef __USERPROG_TSS_H
2 #define __USERPROG_TSS_H
3 #include "stdint.h"
4
5 void tss_init(void);
6 static struct gdt_desc make_gdt_desc(uint32_t *desc_addr, uint32_t limit, uint8_t attr_low, uint8_t attr_high);
7 void update_tss_esp(struct task_struct *pthread);
8 #endif
tss.h
1 ...
2
3 /******************** TSS描述符屬性**********************/
4 #define TSS_DESC_D 0
5 #define TSS_ATTR_HIGH ((DESC_G_4K << 7) + (TSS_DESC_D << 6) + (DESC_L << 5) + (DESC_AVL << 4) + 0x0)
6 #define TSS_ATTR_LOW ((DESC_P << 7) + (DESC_DPL_0 << 5) + (DESC_S_SYS << 4) + DESC_TYPE_TSS)
7
8 #define SELECTOR_TSS ((4 << 3) + (TI_GDT << 2) + RPL0)
9
10 ...
global.h
注釋寫的比較清楚，我們挑重點來講。注意這個函數：
1 /*更新tss中的esp0欄位的值為pthread的0級棧*/ 2 void update_tss_esp(struct task_struct *pthread) 3 { 4 tss.esp0 = (uint32_t *)((uint32_t)pthread + PG_SIZE); 5 }
這個函數的作用就是用來更新TSS中的esp0。我們前面在實現執行緒的時候，執行緒的PCB上有一塊名為中斷棧的區域一直沒有被使用，現在就被用上了。忘記的話點這裡。其實它就是這裡所說的0級棧，用戶進程從3特權級進入0特權級時，CPU會自動從TSS中獲取到0特權級的棧指針，也就是0級棧。
最後還需要修改一下mbr.S和loader.S文件，為什麼呢？原來在loader.S文件中，我們在開頭通過jmp loader_start跳轉到後面執行loader部分， 在這行程式碼後面實現了GDT表的建立，而jmp loader_start這行程式碼是需要佔據3個位元組的內容，這樣就導致GDT表位於記憶體0x903地址處，不利於後面的對齊，所以我們為了讓GDT表位於0x900處，需要移除jmp loader_start這行程式碼，但是我們知道這行程式碼是mbr跳轉執行到的，為了讓mbr直接跳轉到loader部分，我們需要修改mbr.S中的最後跳轉語句，修改為jmp LOADER_BASE_ADDR + 0x206 這個0x206怎麼來的呢，GDT表總共有64個描述符，再加上gdt指針佔用6個位元組，總共便是64*8+6=518個位元組，也就是0x206。這裡就不多啰嗦了，直接將修改好的mbr.S和loader.S附上。
1 %include "boot.inc"
2 section MBR vstart=0x7c00
3 mov ax, cs
4 mov ds, ax
5 mov es, ax
6 mov ss, ax
7 mov fs, ax
8 mov sp, 0x7c00
9 mov ax, 0xb800
10 mov gs, ax
11
12 ;利用int 0x10 的0x06號功能實現清屏
13 mov ax, 0x600
14 mov bx, 0x700
15 mov cx, 0
16 mov dx, 0x184f
17
18 int 0x10
19
20 mov ah, 3
21 mov bh, 0
22
23 int 0x10
24 ;輸出字元串「HELLO MBR」 A表示綠色背景閃爍，4表示前景色為紅色
25 mov byte [gs:0x00],'H'
26 mov byte [gs:0x01],0xA4
27
28 mov byte [gs:0x02],'E'
29 mov byte [gs:0x03],0xA4
30
31 mov byte [gs:0x04],'L'
32 mov byte [gs:0x05],0xA4
33
34 mov byte [gs:0x06],'L'
35 mov byte [gs:0x07],0xA4
36
37 mov byte [gs:0x08],'O'
38 mov byte [gs:0x09],0xA4
39
40 mov byte [gs:0x0A],' '
41 mov byte [gs:0x0B],0xA4
42
43 mov byte [gs:0x0C],'M'
44 mov byte [gs:0x0D],0xA4
45
46 mov byte [gs:0x0E],'B'
47 mov byte [gs:0x0F],0xA4
48
49 mov byte [gs:0x10],'R'
50 mov byte [gs:0x11],0xA4
51
52 mov eax, LOADER_START_SECTOR ;起始扇區lba的地址
53 mov bx, LOADER_BASE_ADDR ;loader將要被寫入的記憶體地址
54 mov cx, 4 ;待讀入的扇區數
55 call rd_disk_m_16 ;調用函數，將loader寫入到記憶體中
56
57 jmp LOADER_BASE_ADDR + 0x206
58
59 ;---------------------------------------
60 ;功能：讀取硬碟n個扇區
61 rd_disk_m_16:
62 mov esi, eax ;備份eax，eax中存放了扇區號，這裡為0x2
63 mov di, cx ;備份cx，cx中存放待讀入的扇區數
64
65 ;讀寫硬碟：
66 ;第一步：設置要讀取的扇區數
67 mov dx, 0x1f2
68 mov al, cl
69 out dx, al
70
71 mov eax, esi
72
73 ;第二步：將lba地址存入到0x1f3 ~ 0x1f6
74 ;lba地址7-0位寫入埠0x1f3
75 mov dx, 0x1f3
76 out dx, al
77
78 ;lba地址15-8位寫入埠0x1f4
79 mov cl, 8
80 shr eax, cl
81 mov dx, 0x1f4
82 out dx, al
83
84 ;lba地址23-16位寫入埠0x1f5
85 shr eax, cl
86 mov dx, 0x1f5
87 out dx, al
88
89 shr eax, cl
90 and al, 0x0f
91 or al, 0xe0
92 mov dx, 0x1f6
93 out dx, al
94
95 ;第三步：向0x1f7埠寫入讀命令，0x20
96 mov dx, 0x1f7
97 mov al, 0x20
98 out dx, al
99
100 ;第四步：檢測硬碟狀態
101 .not_ready:
102 nop
103 in al, dx
104 and al, 0x88
105 cmp al, 0x08
106 jnz .not_ready
107
108 ;第五步：從0x1f0埠讀數據
109 mov ax, di
110 mov dx, 256
111 mul dx
112 mov cx, ax
113 ;di為要讀取的扇區數，一個扇區共有512位元組，每次讀入一個字，總共需要
114 ;di*512/2次，所以di*256
115 mov dx, 0x1f0
116 .go_on_read:
117 in ax, dx
118 mov [bx], ax
119 add bx,2
120 loop .go_on_read
121 ret
122 ;---------------------------------------
123
124 times 510-($-$$) db 0
125 db 0x55, 0xaa
mbr.S
1 %include "boot.inc"
2 section loader vstart=LOADER_BASE_ADDR
3 LOADER_STACK_TOP equ LOADER_BASE_ADDR
4 ;構建gdt及其內部描述符
5 GDT_BASE: dd 0x00000000
6 dd 0x00000000
7 CODE_DESC: dd 0x0000FFFF
8 dd DESC_CODE_HIGH4
9 DATA_STACK_DESC: dd 0x0000FFFF
10 dd DESC_DATA_HIGH4
11 VIDEO_DESC: dd 0x80000007
12 dd DESC_VIDEO_HIGH4
13
14 GDT_SIZE equ $-GDT_BASE
15 GDT_LIMIT equ GDT_SIZE-1
16 times 60 dq 0 ;此處預留60個描述符的空位
17
18 SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0
19 SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0
20 SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0
21
22 ;以下是gdt指針，前2個位元組是gdt界限，後4個位元組是gdt的起始地址
23 gdt_ptr dw GDT_LIMIT
24 dd GDT_BASE
25
26 ;---------------------進入保護模式------------
27 loader_start:
28 ;一、打開A20地址線
29 in al, 0x92
30 or al, 0000_0010B
31 out 0x92, al
32
33 ;二、載入GDT
34 lgdt [gdt_ptr]
35
36 ;三、cr0第0位(pe)置1
37 mov eax, cr0
38 or eax, 0x00000001
39 mov cr0, eax
40
41 jmp dword SELECTOR_CODE:p_mode_start ;刷新流水線
42
43 [bits 32]
44 p_mode_start:
45 mov ax, SELECTOR_DATA
46 mov ds, ax
47 mov es, ax
48 mov ss, ax
49 mov esp, LOADER_STACK_TOP
50 mov ax, SELECTOR_VIDEO
51 mov gs, ax
52
53 mov byte [gs:160], 'p'
54 ;---------------------------------------
55
56 ;------------------開啟分頁機制-----------------
57 ;一、創建頁目錄表並初始化頁記憶體點陣圖
58 call setup_page
59
60 ;將描述符表地址及偏移量寫入記憶體gdt_ptr，一會兒用新地址重新載入
61 sgdt [gdt_ptr]
62 ;將gdt描述符中影片段描述符中的段基址+0xc0000000
63 mov ebx, [gdt_ptr + 2]
64 or dword [ebx + 0x18 + 4], 0xc0000000
65
66 ;將gdt的基址加上0xc0000000使其成為內核所在的高地址
67 add dword [gdt_ptr + 2], 0xc0000000
68
69 add esp, 0xc0000000 ;將棧指針同樣映射到內核地址
70
71 ;二、將頁目錄表地址賦值給cr3
72 mov eax, PAGE_DIR_TABLE_POS
73 mov cr3, eax
74
75 ;三、打開cr0的pg位
76 mov eax, cr0
77 or eax, 0x80000000
78 mov cr0, eax
79
80 ;在開啟分頁後，用gdt新的地址重新載入
81 lgdt [gdt_ptr]
82 mov byte [gs:160], 'H'
83 mov byte [gs:162], 'E'
84 mov byte [gs:164], 'L'
85 mov byte [gs:166], 'L'
86 mov byte [gs:168], 'O'
87 mov byte [gs:170], ' '
88 mov byte [gs:172], 'P'
89 mov byte [gs:174], 'A'
90 mov byte [gs:176], 'G'
91 mov byte [gs:178], 'E'
92
93 ;---------------------------------------------
94
95 ;--------------------拷貝內核文件並進入kernel--------------------------
96 mov eax, KERNEL_START_SECTOR ;kernel.bin所在的扇區號 0x09
97 mov ebx, KERNEL_BIN_BASE_ADDR ;從磁碟讀出後，寫入到ebx指定的地址0x70000
98 mov ecx, 200 ;讀入的扇區數
99
100 call rd_disk_m_32
101
102 ;由於一直處在32位下，原則上不需要強制刷新，但是以防萬一還是加上
103 ;跳轉到kernel處
104 jmp SELECTOR_CODE:enter_kernel
105
106 enter_kernel:
107 call kernel_init
108 mov esp, 0xc009f000 ;更新棧底指針
109 jmp KERNEL_ENTRY_POINT ;內核地址0xc0001500
110 ;jmp $
111 ;---------------------將kernel.bin中的segment拷貝到指定的地址
112 kernel_init:
113 xor eax, eax
114 xor ebx, ebx ;ebx記錄程式頭表地址
115 xor ecx, ecx ;cx記錄程式頭表中的program header數量
116 xor edx, edx ;dx記錄program header 尺寸，即e_phentsize
117
118 ;偏移文件42位元組處的屬性是e_phentsize， 表示program header大小
119 mov dx, [KERNEL_BIN_BASE_ADDR + 42]
120
121 ;偏移文件28位元組處的屬性是e_phoff
122 mov ebx, [KERNEL_BIN_BASE_ADDR + 28]
123
124 add ebx, KERNEL_BIN_BASE_ADDR
125 mov cx, [KERNEL_BIN_BASE_ADDR + 44]
126
127 .each_segment:
128 cmp byte [ebx + 0], PT_NULL
129 je .PTNULL
130
131 ;為函數memcpy壓入參數，參數是從右往左壓入
132 push dword [ebx + 16]
133 mov eax, [ebx + 4]
134 add eax, KERNEL_BIN_BASE_ADDR
135 push eax
136 push dword [ebx + 8]
137 call mem_cpy
138 add esp, 12
139
140 .PTNULL:
141 add ebx, edx
142 loop .each_segment
143 ret
144
145 ;-----------逐位元組拷貝mem_cpy(dst, src, size)
146 mem_cpy:
147 cld
148 push ebp
149 mov ebp, esp
150 push ecx
151 mov edi, [ebp + 8]
152 mov esi, [ebp + 12]
153 mov ecx, [ebp + 16]
154 rep movsb
155
156 pop ecx
157 pop ebp
158 ret
159 ;---------------------------------------------------
160
161
162
163
164 ;--------------函數聲明------------------------
165 ;setup_page：(功能)設置分頁------------
166 setup_page:
167 ;先把頁目錄佔用的空間逐位元組清0
168 mov ecx, 4096
169 mov esi, 0
170 .clear_page_dir:
171 mov byte [PAGE_DIR_TABLE_POS + esi], 0
172 inc esi
173 loop .clear_page_dir
174
175 ;開始創建頁目錄項
176 .create_pde:
177 mov eax, PAGE_DIR_TABLE_POS
178 add eax, 0x1000 ;此時eax為第一個頁表的位置
179 mov ebx, eax
180
181 ;下面將頁目錄項0和0xc00都存為第一個頁表的地址，每個頁表表示4MB記憶體
182 ;頁目錄表的屬性RW和P位為1,US為1，表示用戶屬性，所有特權級別都可以訪問
183 or eax, PG_US_U | PG_RW_W | PG_P
184
185 ;在頁目錄表中的第1個目錄項中寫入第一個頁表的地址(0x101000)和屬性
186 mov [PAGE_DIR_TABLE_POS + 0x0], eax
187
188 mov [PAGE_DIR_TABLE_POS + 0xc00], eax
189
190 ;使最後一個目錄項指向頁目錄表自己的地址
191 sub eax, 0x1000
192 mov [PAGE_DIR_TABLE_POS + 4092], eax
193
194 ;下面創建頁表項(PTE)
195 mov ecx, 256 ;1M低端記憶體/每頁大小4K=256
196 mov esi, 0
197 mov edx, PG_US_U | PG_RW_W | PG_P
198 .create_pte: ;創建page table entry
199 mov [ebx + esi*4], edx
200 add edx, 4096
201 inc esi
202 loop .create_pte
203
204 ;創建內核其他頁表的PDE
205 mov eax, PAGE_DIR_TABLE_POS
206 add eax, 0x2000 ;此時eax為第二個頁表的位置
207 or eax, PG_US_U | PG_RW_W | PG_P
208 mov ebx, PAGE_DIR_TABLE_POS
209 mov ecx, 254 ;範圍為第769～1022的所有目錄項數量
210 mov esi, 769
211 .create_kernel_pde:
212 mov [ebx + esi*4], eax
213 inc esi
214 add eax, 0x1000
215 loop .create_kernel_pde
216 ret
217
218
219 ;rd_disk_m_32：(功能)讀取硬碟n個扇區------------
220 rd_disk_m_32:
221 mov esi,eax ;備份eax，eax中存放了扇區號
222 mov di,cx ;備份cx，cx中存放待讀入的扇區數
223
224 ;讀寫硬碟：
225 ;第一步：設置要讀取的扇區數
226 mov dx,0x1f2
227 mov al,cl
228 out dx,al
229
230 mov eax,esi
231
232 ;第二步：將lba地址存入到0x1f3 ~ 0x1f6
233 ;lba地址7-0位寫入埠0x1f3
234 mov dx,0x1f3
235 out dx,al
236
237 ;lba地址15-8位寫入埠0x1f4
238 mov cl,8
239 shr eax,cl
240 mov dx,0x1f4
241 out dx,al
242
243 ;lba地址23-16位寫入埠0x1f5
244 shr eax,cl
245 mov dx,0x1f5
246 out dx,al
247
248 shr eax,cl
249 and al,0x0f
250 or al,0xe0
251 mov dx,0x1f6
252 out dx,al
253
254 ;第三步：向0x1f7埠寫入讀命令，0x20
255 mov dx,0x1f7
256 mov al,0x20
257 out dx,al
258
259 ;第四步：檢測硬碟狀態
260 .not_ready:
261 nop
262 in al,dx
263 and al,0x88
264 cmp al,0x08
265 jnz .not_ready
266
267 ;第五步：從0x1f0埠讀數據
268 mov ax,di
269 mov dx,256
270 mul dx
271 mov cx,ax
272 ;di為要讀取的扇區數，一個扇區共有512位元組，每次讀入一個字，總共需要
273 ;di*512/2次，所以di*256
274 mov dx,0x1f0
275 .go_on_read:
276 in ax,dx
277 mov [ebx],ax
278 add ebx,2
279 loop .go_on_read
280 ret
281 ;----------------------------------------------
loader.S
運行測試後，tss成功初始化。
在bochs控制台輸入info gdt可以看到GDT表的內容，可以看到現在有7個描述符，在GDT中第4個描述符是剛安裝好的TSS段描述符，其顯示為32-Bit TSS(Busy)，說明TSS的B位被CPU置1了，TSS已經生效了。
本回到此結束，預知後事如何，請看下回分解。
